gtkpasman/configure.ac

#                                               -*- Autoconf -*-
# Process this file with autoconf to produce a configure script.

AC_PREREQ([2.64])
AC_INIT([GtkPasman], [0.12.2], [jcpp@users.sourceforge.net])
AC_CONFIG_SRCDIR([src/configread.c])
AC_CONFIG_HEADERS([config.h])
IT_PROG_INTLTOOL

AM_INIT_AUTOMAKE

# Checks for programs.
AC_PROG_CC
AM_PROG_CC_C_O

# Checks for libraries.
AC_ARG_WITH([gtk2], AS_HELP_STRING([--with-gtk2], [Build UI with GTK+2 instead of GTK+3]))
AM_CONDITIONAL(USE_GTK2, [test "x$with_gtk2" = "xyes"])

AS_IF([test "x$with_gtk2" = "xyes"], [
  PKG_CHECK_MODULES([GTK], [gtk+-2.0 >= 2.10])
],[
  PKG_CHECK_MODULES([GTK], [gtk+-3.0 >= 3.4.0])
])

# i18n
AC_ARG_ENABLE(nls,
  AS_HELP_STRING([--enable-nls], [Enable Native Language Support using gettext]),
  [use_nls="$enableval"],
  [use_nls="yes"])

AM_CONDITIONAL(DISABLE_NLS, [ test "x${use_nls}" = "xno" ])

if test "x${use_nls}" = "xyes"; then
  GETTEXT_PACKAGE=gtkpasman
  AC_SUBST([GETTEXT_PACKAGE])
  AC_DEFINE_UNQUOTED([GETTEXT_PACKAGE], "$GETTEXT_PACKAGE", [Gettext package])
  AM_GLIB_GNU_GETTEXT
fi

# GSettings is enabled by default
AC_ARG_ENABLE(gsettings,
  AS_HELP_STRING([--disable-gsettings], [Use plain text configuration file *NOT RECOMMANDED*]),
  [use_gsettings="$enableval"],
  [use_gsettings="yes"])

AM_CONDITIONAL(DISABLE_GSETTINGS, [ test "x${use_gsettings}" = "xno"])

if test "x${use_gsettings}" = "xyes"; then
  PKG_CHECK_MODULES([GSETTINGS],[gio-2.0 >= 2.25.0])
  GLIB_GSETTINGS
fi

# Disable GPG.
AC_ARG_ENABLE(gpg,
  AS_HELP_STRING([--disable-gpg], [Use plain text passwd file database *NOT RECOMMANDED*]),
  [use_gpg="$enableval"],
  [use_gpg="yes"])

AM_CONDITIONAL(DISABLE_GPG, [ test "x${use_gpg}" = "xno" ])

# Checks for header files.
AC_CHECK_HEADERS([stdlib.h string.h unistd.h getopt.h stdio.h])

# Checks for typedefs, structures, and compiler characteristics.

# Checks for library functions.
AC_CHECK_FUNCS([strerror strstr popen])

AC_CONFIG_FILES([Makefile
  src/Makefile
  data/Makefile
  po/Makefile.in
])


AC_OUTPUT